***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 16, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZT52-C30S A K
.param
+vc0 = 6.046e-11	 vc1 = 5.053e-11	 vc2 = 1.000		 vc3 = 5.651e-10	 vc4 = 3.747e-2
+tc1 = 3.051e-2		 tc2 = 1.021e-2		 tc3 = 4.941e-3		 tc4 = 1.721e-3		   
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter ***
+level = 1   
***** dc model parameter ***
+ is = 1.195e-13	   n = 1.178		  rs = 5.577e-1		ikf = 1.016e-3
+ibv = 5e-3		 nbv = 1		  bv = 30
***** capacitance parameter ***
+cjo = 1.601e-10	   m = 3.564e-1		  vj = 6.496e-1
+ fc = 0.5                      
***** temperature coefficient ***
+tnom = 25		  eg = 1.053		 xti = 3
+trs1 = 1.024e-4	trs2 = 1.347e-6		tbv1 = 7.015e-4		tbv2 = 1.726e-7		tikf = 1e-2
.ends BZT52-C30S
*$
